nprocs_le Subroutine

  subroutine nprocs_le(report_unit)
    use species, only : nspec
    use kt_grids, only: naky, ntheta0
    use theta_grid, only: ntgrid
    use gs2_layouts, only: layout, factors
    implicit none
    integer, intent(in) :: report_unit
    integer :: nkxfacs, nkyfacs, nspfacs, ntgfacs
    integer, dimension(:,:), allocatable :: facs
    integer :: maxfacs
    integer, allocatable, dimension(:):: spfacs, tgfacs, kxfacs, kyfacs
    integer, dimension(4) :: nfac, sdim
    character(3), dimension(4):: sym

    write (report_unit, fmt="('#proc sweetspots for le_lo, up to:',i8)") npmax

    maxfacs=max(nspec,2*ntgrid+1,ntheta0,naky)/2+1
    allocate (spfacs(maxfacs),tgfacs(maxfacs),kxfacs(maxfacs),kyfacs(maxfacs),facs(maxfacs,4))
    call factors (nspec, nspfacs, spfacs)
    call factors (2*ntgrid+1, ntgfacs, tgfacs)
    call factors (ntheta0, nkxfacs, kxfacs)
    call factors (naky, nkyfacs, kyfacs)

    select case (layout)
    case ('lexys','xyles','lxyes')
       sym = (/ "s  ","y  ","x  ","tg " /)
       sdim = (/ nspec, naky, ntheta0, 2*ntgrid+1 /)
       nfac= (/ nspfacs, nkyfacs, nkxfacs, ntgfacs /)
       facs(:,1)=spfacs; facs(:,2)=kyfacs
       facs(:,3)=kxfacs; facs(:,4)=tgfacs
       call wsweetspots(sym,sdim,nfac,facs,npmax,LUN=report_unit)
    case ('lyxes','yxles','yxels')
       sym = (/ "s  ","x  ","y  ","tg " /)
       sdim = (/ nspec, ntheta0, naky, 2*ntgrid+1 /)
       nfac= (/ nspfacs, nkxfacs, nkyfacs, ntgfacs /)
       facs(:,1)=spfacs; facs(:,2)=kxfacs
       facs(:,3)=kyfacs; facs(:,4)=tgfacs
       call wsweetspots(sym,sdim,nfac,facs,npmax,LUN=report_unit)
    end select
    deallocate (spfacs,tgfacs,kxfacs,kyfacs,facs)
  end subroutine nprocs_le